Erlang 完善后实例

增加健壮性后的完整示例

让我们改进 Messager 程序以增加该程序的健壮性： 

  1. %%% Message passing utility.  
  2. %%% User interface:
  3. %%% login(Name)
  4. %%%     One user at a time can log in from each Erlang node in the
  5. %%%     system messenger: and choose a suitable Name. If the Name
  6. %%%     is already logged in at another node or if someone else is
  7. %%%     already logged in at the same node, login will be rejected
  8. %%%     with a suitable error message.
  9. %%% logoff()
  10. %%%     Logs off anybody at that node
  11. %%% message(ToName, Message)
  12. %%%     sends Message to ToName. Error messages if the user of this 
  13. %%%     function is not logged on or if ToName is not logged on at
  14. %%%     any node.
  15. %%%
  16. %%% One node in the network of Erlang nodes runs a server which maintains
  17. %%% data about the logged on users. The server is registered as "messenger"
  18. %%% Each node where there is a user logged on runs a client process registered
  19. %%% as "mess_client" 
  20. %%%
  21. %%% Protocol between the client processes and the server
  22. %%% ----------------------------------------------------
  23. %%% 
  24. %%% To server: {ClientPid, logon, UserName}
  25. %%% Reply {messenger, stop, user_exists_at_other_node} stops the client
  26. %%% Reply {messenger, logged_on} logon was successful
  27. %%%
  28. %%% When the client terminates for some reason
  29. %%% To server: {'EXIT', ClientPid, Reason}
  30. %%%
  31. %%% To server: {ClientPid, message_to, ToName, Message} send a message
  32. %%% Reply: {messenger, stop, you_are_not_logged_on} stops the client
  33. %%% Reply: {messenger, receiver_not_found} no user with this name logged on
  34. %%% Reply: {messenger, sent} Message has been sent (but no guarantee)
  35. %%%
  36. %%% To client: {message_from, Name, Message},
  37. %%%
  38. %%% Protocol between the "commands" and the client
  39. %%% ---------------------------------------------- 
  40. %%%
  41. %%% Started: messenger:client(Server_Node, Name)
  42. %%% To client: logoff
  43. %%% To client: {message_to, ToName, Message}
  44. %%%
  45. %%% Configuration: change the server_node() function to return the
  46. %%% name of the node where the messenger server runs
  48. -module(messenger).
  49. -export([start_server/0, server/0, 
  50.          logon/1, logoff/0, message/2, client/2]).
  52. %%% Change the function below to return the name of the node where the
  53. %%% messenger server runs
  54. server_node() ->
  55.     messenger@super.
  57. %%% This is the server process for the "messenger"
  58. %%% the user list has the format [{ClientPid1, Name1},{ClientPid22, Name2},...]
  59. server() ->
  60.     process_flag(trap_exit, true),
  61.     server([]).
  63. server(User_List) ->
  64.     receive
  65.         {From, logon, Name} ->
  66.             New_User_List = server_logon(From, Name, User_List),
  67.             server(New_User_List);
  68.         {'EXIT', From, _} ->
  69.             New_User_List = server_logoff(From, User_List),
  70.             server(New_User_List);
  71.         {From, message_to, To, Message} ->
  72.             server_transfer(From, To, Message, User_List),
  73.             io:format("list is now: ~p~n", [User_List]),
  74.             server(User_List)
  75.     end.
  77. %%% Start the server
  78. start_server() ->
  79.     register(messenger, spawn(messenger, server, [])).
  81. %%% Server adds a new user to the user list
  82. server_logon(From, Name, User_List) ->
  83.     %% check if logged on anywhere else
  84.     case lists:keymember(Name, 2, User_List) of
  85.         true ->
  86.             From ! {messenger, stop, user_exists_at_other_node},  %reject logon
  87.             User_List;
  88.         false ->
  89.             From ! {messenger, logged_on},
  90.             link(From),
  91.             [{From, Name} | User_List]        %add user to the list
  92.     end.
  94. %%% Server deletes a user from the user list
  95. server_logoff(From, User_List) ->
  96.     lists:keydelete(From, 1, User_List).
  98. %%% Server transfers a message between user
  99. server_transfer(From, To, Message, User_List) ->
  100.     %% check that the user is logged on and who he is
  101.     case lists:keysearch(From, 1, User_List) of
  102.         false ->
  103.             From ! {messenger, stop, you_are_not_logged_on};
  104.         {value, {_, Name}} ->
  105.             server_transfer(From, Name, To, Message, User_List)
  106.     end.
  108. %%% If the user exists, send the message
  109. server_transfer(From, Name, To, Message, User_List) ->
  110.     %% Find the receiver and send the message
  111.     case lists:keysearch(To, 2, User_List) of
  112.         false ->
  113.             From ! {messenger, receiver_not_found};
  114.         {value, {ToPid, To}} ->
  115.             ToPid ! {message_from, Name, Message}, 
  116.             From ! {messenger, sent} 
  117.     end.
  119. %%% User Commands
  120. logon(Name) ->
  121.     case whereis(mess_client) of 
  122.         undefined ->
  123.             register(mess_client, 
  124.                      spawn(messenger, client, [server_node(), Name]));
  125.         _ -> already_logged_on
  126.     end.
  128. logoff() ->
  129.     mess_client ! logoff.
  131. message(ToName, Message) ->
  132.     case whereis(mess_client) of % Test if the client is running
  133.         undefined ->
  134.             not_logged_on;
  135.         _ -> mess_client ! {message_to, ToName, Message},
  136.              ok
  137. end.
  139. %%% The client process which runs on each user node
  140. client(Server_Node, Name) ->
  141.     {messenger, Server_Node} ! {self(), logon, Name},
  142.     await_result(),
  143.     client(Server_Node).
  145. client(Server_Node) ->
  146.     receive
  147.         logoff ->
  148.             exit(normal);
  149.         {message_to, ToName, Message} ->
  150.             {messenger, Server_Node} ! {self(), message_to, ToName, Message},
  151.             await_result();
  152.         {message_from, FromName, Message} ->
  153.             io:format("Message from ~p: ~p~n", [FromName, Message])
  154.     end,
  155.     client(Server_Node).
  157. %%% wait for a response from the server
  158. await_result() ->
  159.     receive
  160.         {messenger, stop, Why} -> % Stop the client 
  161.             io:format("~p~n", [Why]),
  162.             exit(normal);
  163.         {messenger, What} ->  % Normal response
  164.             io:format("~p~n", [What])
  165.     after 5000 ->
  166.             io:format("No response from server~n", []),
  167.             exit(timeout)
  168.     end.

主要有如下几处改动:

Messager 服务器捕捉进程退出。如果它收到进程终止信号，{'EXIT',From,Reason}，则说明客户端进程已经终止或者由于下面的原因变得不可达：

  • 用户主动退出登录（取消了 “logoff” 消息）。
  • 与客户端连接的网络已经断开。
  • 客户进程所处的结点崩溃。
  • 客户进程执行了某些非法操作。

如果收到上面所述的退出信号，服务器调用 server_logoff 函数将 {From, Name} 元组从 User_Lists 列表中删除。如果服务端所在的结点崩溃了，那么系统将将自动产生进程终止信号，并将其发送给所有的客户端进程：'EXIT',MessengerPID,noconnection}，客户端进程收到该消息后会终止自身。

同样，在 await_result 函数中引入了一个 5 秒钟的定时器。也就是说，如果服务器 5 秒钟之类没有回复客户端，则客户端终止执行。这个只是在服务端与客户端建立连接前的登录阶段需要。

一个非常有意思的例子是如果客户端在服务端建立连接前终止会发生什么情况呢？需要特别注意，如果一个进程与另一个不存在的进程建立连接，则会收到一个终止信号 {'EXIT',From, noproc}。这就好像连接建立后进程立马就结束了一样。